Add new hex.search

Author: josevalim

lib/hex/utils.ex

@@ -333,16 +333,30 @@ defmodule Hex.Utils do
   def open_cmd(path) do
     case :os.type() do
       {:win32, _} ->
-        {"cmd", ["/c", "start", path]}
+        {"cmd", win_cmd_args(path)}
 
       {:unix, :darwin} ->
-        {"open", [path], []}
+        {"open", [path]}
 
       {:unix, _} ->
-        {"xdg-open", [path], []}
+        cond do
+          System.find_executable("xdg-open") ->
+            {"xdg-open", [path]}
+
+          # When inside WSL
+          System.find_executable("cmd.exe") ->
+            {"cmd.exe", win_cmd_args(path)}
+
+          true ->
+            {"open", [path]}
+        end
     end
   end
 
+  defp win_cmd_args(path) do
+    ["/c", "start", String.replace(path, "&", "^&")]
+  end
+
   @doc """
   Opens a file or URL with the system's default handler.
 
@@ -355,12 +369,12 @@ defmodule Hex.Utils do
   end
 
   if Mix.env() == :test do
-    defp system_cmd({cmd, args, options}) do
-      send(self(), {:hex_system_cmd, cmd, args, options})
+    defp system_cmd({cmd, args}) do
+      send(self(), {:hex_system_cmd, cmd, args})
     end
   else
-    defp system_cmd({cmd, args, options}) do
-      System.cmd(cmd, args, options)
+    defp system_cmd({cmd, args}) do
+      System.cmd(cmd, args)
     end
   end
 end

lib/mix/tasks/hex.search.ex

@@ -1,50 +1,96 @@
 defmodule Mix.Tasks.Hex.Search do
   use Mix.Task
 
-  @shortdoc "Searches for package names"
+  @shortdoc "Open and perform searches"
 
   @moduledoc """
-  Displays packages matching the given search query.
+  Open and perform searches.
 
-  If you are authenticated it will additionally search all organizations you are member of.
+  When invoked without arguments, it opens up a search page on
+  https://hexdocs.pm with all of your dependencies selected:
 
-      $ mix hex.search PACKAGE
+      $ mix hex.search
 
-  ## Command line options
+  You may also pass command line flags, to execute searches
+  via the command line, according to the modes below.
+
+  ## Package search
+
+  Specify `--package PACKAGE` to search for a given package.
+
+      $ mix hex.search --package PACKAGE
+
+  If you are authenticated, it will additionally search all organizations
+  you are member of.
+
+  ### Options
 
     * `--organization ORGANIZATION` - Set this for private packages belonging to an organization
 
   """
   @behaviour Hex.Mix.TaskDescription
 
-  @switches [organization: :string, all_organizations: :boolean]
+  @switches [organization: :string, package: :string]
 
   @impl true
   def run(args) do
-    Hex.start()
-    {opts, args} = OptionParser.parse!(args, strict: @switches)
-
     case args do
-      [package] ->
-        search_package(package, opts[:organization])
+      [] ->
+        hexdocs_search()
 
       _ ->
-        Mix.raise("""
-        Invalid arguments, expected:
-
-        mix hex.search PACKAGE
-        """)
+        {opts, args} = OptionParser.parse!(args, strict: @switches)
+
+        case args do
+          [package] ->
+            Mix.shell().error(
+              "mix hex.search PACKAGE is deprecated, use --package PACKAGE instead"
+            )
+
+            package_search(package, opts[:organization])
+
+          _ ->
+            package = opts[:package]
+
+            if is_binary(package) and args == [] do
+              package_search(package, opts[:organization])
+            else
+              Mix.raise("""
+              Invalid arguments, expected:
+
+              mix hex.search
+              mix hex.search --package PACKAGE
+              """)
+            end
+        end
     end
   end
 
   @impl true
   def tasks() do
     [
-      {"PACKAGE", "Searches for package names"}
+      {"", "Opens up hexdocs.pm with your dependencies"},
+      {"--package PACKAGE", "Searches for package names"}
     ]
   end
 
-  defp search_package(package, organization) do
+  defp hexdocs_search() do
+    Mix.Tasks.Deps.Loadpaths.run(["--no-compile", "--no-listeners"])
+    Hex.start()
+
+    packages =
+      for {_app, info} <- Mix.Dep.Lock.read(),
+          %{repo: "hexpm", name: name, version: version} <- [Hex.Utils.lock(info)] do
+        "#{name}:#{version}"
+      end
+      |> Enum.join(",")
+      |> URI.encode_www_form()
+
+    Hex.Utils.system_open("https://hexdocs.pm/?packages=#{packages}&q=")
+  end
+
+  defp package_search(package, organization) do
+    Hex.start()
     auth = Mix.Tasks.Hex.auth_info(:read, auth_inline: false)
 
     Hex.API.Package.search(organization, package, auth)

test/mix/tasks/hex.docs_test.exs

@@ -203,7 +203,7 @@ defmodule Mix.Tasks.Hex.DocsTest do
       fetched_msg = "Docs fetched: #{docs_home}/#{org_dir}/#{package}/#{latest_version}"
       browser_open_msg = "#{docs_home}/#{org_dir}/#{package}/#{latest_version}/index.html"
       assert_received {:mix_shell, :info, [^fetched_msg]}
-      assert_received {:hex_system_cmd, _cmd, browser_open_cmd, _}
+      assert_received {:hex_system_cmd, _cmd, browser_open_cmd}
       assert Enum.fetch!(browser_open_cmd, -1) == browser_open_msg
     end)
   end
@@ -221,7 +221,7 @@ defmodule Mix.Tasks.Hex.DocsTest do
       fetched_msg = "Docs fetched: #{docs_home}/#{org_dir}/#{package}/#{latest_version}"
       browser_open_msg = "#{docs_home}/#{org_dir}/#{package}/#{latest_version}/docs_package.epub"
       assert_received {:mix_shell, :info, [^fetched_msg]}
-      assert_received {:hex_system_cmd, _cmd, browser_open_cmd, _}
+      assert_received {:hex_system_cmd, _cmd, browser_open_cmd}
       assert Enum.fetch!(browser_open_cmd, -1) == browser_open_msg
     end)
   end
@@ -240,7 +240,7 @@ defmodule Mix.Tasks.Hex.DocsTest do
       fetched_msg = "Docs fetched: #{docs_home}/#{org_dir}/#{package}/#{version}"
       browser_open_msg = "#{docs_home}/#{org_dir}/#{package}/#{version}/index.html"
       assert_received {:mix_shell, :info, [^fetched_msg]}
-      assert_received {:hex_system_cmd, _cmd, browser_open_cmd, _}
+      assert_received {:hex_system_cmd, _cmd, browser_open_cmd}
       assert Enum.fetch!(browser_open_cmd, -1) == browser_open_msg
 
       Mix.Tasks.Hex.Docs.run(["fetch", package, version])
@@ -265,14 +265,14 @@ defmodule Mix.Tasks.Hex.DocsTest do
 
       Mix.Tasks.Hex.Docs.run(["offline", package, version])
       browser_open_msg = "#{docs_home}/#{package}/#{version}/index.html"
-      assert_received {:hex_system_cmd, _cmd, browser_open_cmd, _}
+      assert_received {:hex_system_cmd, _cmd, browser_open_cmd}
       assert Enum.fetch!(browser_open_cmd, -1) == browser_open_msg
     end)
   end
 
   test "open docs online" do
     Mix.Tasks.Hex.Docs.run(["online", "ecto"])
-    assert_received {:hex_system_cmd, _cmd, browser_open_cmd, _}
+    assert_received {:hex_system_cmd, _cmd, browser_open_cmd}
     assert Enum.fetch!(browser_open_cmd, -1) == "https://hexdocs.pm/ecto"
   end
 
@@ -283,7 +283,7 @@ defmodule Mix.Tasks.Hex.DocsTest do
     in_tmp("docs", fn ->
       Mix.Dep.Lock.write(%{docs_package: {:hex, :docs_package, "1.1.1"}})
       Mix.Tasks.Hex.Docs.run(["online", "docs_package"])
-      assert_received {:hex_system_cmd, _cmd, browser_open_cmd, _}
+      assert_received {:hex_system_cmd, _cmd, browser_open_cmd}
       assert Enum.fetch!(browser_open_cmd, -1) == "https://hexdocs.pm/docs_package/1.1.1"
     end)
   end
@@ -295,7 +295,7 @@ defmodule Mix.Tasks.Hex.DocsTest do
     in_tmp("docs", fn ->
       Mix.Dep.Lock.write(%{docs_package: {:hex, :docs_package, "1.1.1"}})
       Mix.Tasks.Hex.Docs.run(["online", "docs_package", "--latest"])
-      assert_received {:hex_system_cmd, _cmd, browser_open_cmd, _}
+      assert_received {:hex_system_cmd, _cmd, browser_open_cmd}
       assert Enum.fetch!(browser_open_cmd, -1) == "https://hexdocs.pm/docs_package"
     end)
   end
@@ -314,7 +314,7 @@ defmodule Mix.Tasks.Hex.DocsTest do
       fetched_msg = "Docs fetched: #{docs_home}/hexpm/#{package}/#{version}"
       browser_open_msg = "#{docs_home}/hexpm/#{package}/#{version}/index.html"
       assert_received {:mix_shell, :info, [^fetched_msg]}
-      assert_received {:hex_system_cmd, _cmd, browser_open_cmd, _}
+      assert_received {:hex_system_cmd, _cmd, browser_open_cmd}
       assert Enum.fetch!(browser_open_cmd, -1) == browser_open_msg
       assert File.exists?("#{docs_home}/hexpm/#{package}/#{version}")
     end)

test/mix/tasks/hex.search_test.exs

@@ -1,46 +1,68 @@
 defmodule Mix.Tasks.Hex.SearchTest do
   use HexTest.IntegrationCase
 
-  test "search" do
-    Mix.Tasks.Hex.Search.run(["doc"])
-    assert_received {:mix_shell, :info, ["ex_doc" <> ex_doc]}
-    assert_received {:mix_shell, :info, ["only_doc" <> only_doc]}
-    assert ex_doc =~ ~r"\w*0\.1\.0.*http://localhost:4043/packages/ex_doc"
-    assert only_doc =~ ~r"\w*0\.1\.0.*http://localhost:4043/packages/only_doc"
-  end
+  describe "hexdocs" do
+    test "no args" do
+      Mix.Tasks.Hex.Search.run([])
+      assert_received {:hex_system_cmd, "open", ["https://hexdocs.pm/?packages=" <> packages]}
 
-  test "empty search" do
-    Mix.Tasks.Hex.Search.run(["bloopdoopbloop"])
-    assert_received {:mix_shell, :info, ["No packages found"]}
+      vsn = Application.spec(:plug, :vsn)
+      assert packages =~ URI.encode_www_form("plug:#{vsn},")
+      assert String.ends_with?(packages, "&q=")
+    end
   end
 
-  test "search all private packages" do
-    in_tmp(fn ->
-      set_home_tmp()
-      auth = Hexpm.new_user("searchuser1", "[email protected]", "password", "searchuser1")
-      Hexpm.new_repo("searchrepo1", auth)
-      Hex.State.put(:api_key, auth[:key])
+  describe "package" do
+    test "backwards compatibility" do
+      Mix.Tasks.Hex.Search.run(["bloopdoopbloop"])
+
+      assert_received {:mix_shell, :error,
+                       ["mix hex.search PACKAGE is deprecated, use --package PACKAGE instead"]}
 
-      Mix.Tasks.Hex.Search.run(["doc"])
+      assert_received {:mix_shell, :info, ["No packages found"]}
+    end
 
+    test "no results" do
+      Mix.Tasks.Hex.Search.run(["--package", "bloopdoopbloop"])
+      assert_received {:mix_shell, :info, ["No packages found"]}
+    end
+
+    test "public packages" do
+      Mix.Tasks.Hex.Search.run(["--package", "doc"])
       assert_received {:mix_shell, :info, ["ex_doc" <> ex_doc]}
       assert_received {:mix_shell, :info, ["only_doc" <> only_doc]}
       assert ex_doc =~ ~r"\w*0\.1\.0.*http://localhost:4043/packages/ex_doc"
       assert only_doc =~ ~r"\w*0\.1\.0.*http://localhost:4043/packages/only_doc"
-    end)
-  end
+    end
+
+    test "all private packages" do
+      in_tmp(fn ->
+        set_home_tmp()
+        auth = Hexpm.new_user("searchuser1", "[email protected]", "password", "searchuser1")
+        Hexpm.new_repo("searchrepo1", auth)
+        Hex.State.put(:api_key, auth[:key])
+
+        Mix.Tasks.Hex.Search.run(["--package", "doc"])
+
+        assert_received {:mix_shell, :info, ["ex_doc" <> ex_doc]}
+        assert_received {:mix_shell, :info, ["only_doc" <> only_doc]}
+        assert ex_doc =~ ~r"\w*0\.1\.0.*http://localhost:4043/packages/ex_doc"
+        assert only_doc =~ ~r"\w*0\.1\.0.*http://localhost:4043/packages/only_doc"
+      end)
+    end
 
-  test "search private package" do
-    in_tmp(fn ->
-      set_home_tmp()
-      auth = Hexpm.new_user("searchuser2", "[email protected]", "password", "searchuser2")
-      Hexpm.new_repo("searchrepo2", auth)
-      Hex.State.put(:api_key, auth[:key])
+    test "org packages" do
+      in_tmp(fn ->
+        set_home_tmp()
+        auth = Hexpm.new_user("searchuser2", "[email protected]", "password", "searchuser2")
+        Hexpm.new_repo("searchrepo2", auth)
+        Hex.State.put(:api_key, auth[:key])
 
-      Mix.Tasks.Hex.Search.run(["doc", "--organization", "searchrepo2"])
+        Mix.Tasks.Hex.Search.run(["--package", "doc", "--organization", "searchrepo2"])
 
-      refute_received {:mix_shell, :info, ["ex_doc" <> _]}
-      refute_received {:mix_shell, :info, ["only_doc" <> _]}
-    end)
+        refute_received {:mix_shell, :info, ["ex_doc" <> _]}
+        refute_received {:mix_shell, :info, ["only_doc" <> _]}
+      end)
+    end
   end
 end